;---------- ---------- ---------- ---------- ----------
; 作成者のURL ---> http://www.setsuki.com/
;---------- ---------- ---------- ---------- ----------



;========== ========== ========== ========== ==========
; MAGファイル表示モジュール
;---------- ---------- ---------- ---------- ----------
;
; mag_load "filename",p1
; "filename" : ロードするファイル名
; p1=0〜1(0) : 画像ロードモード
;
;	※ stat には色bitを返します。
;	　 表示に失敗した時は -1 を返します。
;
;========== ========== ========== ========== ==========

; --- 参考 ---
; [ まぐろーだー仕様書・非売品 ]
; Woody.RINN著
;
; [ xmagv - X Window System用のまぐろーだー ]
; http://lena.oersted.co.jp/~yav/soft/



#module
;---------- ---------- ---------- ---------- ----------
#deffunc mag_load str file, int p1
mref stt,64

	; ファイルの存在をチェック
	exist file : if strsize<1 : stt=-1 : return
	len=strsize

	; MAG ファイルのチェック
	chk=0 : bload file,chk,4
	if ( chk != 0x494B414D ) : stt=-1 : return

	; ファイルを読み込み
	sdim buf,len : bload file,buf,len

	; ヘッダ位置を取得
	i=32 : repeat len-i : if ( peek(buf,i) == 0 ) : break
	i++ : loop

	; パレットの色数取得
	scrn = peek(buf,i+3)
	if scrn&128 : pbit=8 : pal=256 : else {
		pbit=4 : if scrn&2 : pal=8 : else : pal=16
	}

	; 画像サイズを計算？
	px1 = wpeek(buf,i+ 4) : imgx = wpeek(buf,i+ 8) - px1 +1
	py1 = wpeek(buf,i+ 6) : imgy = wpeek(buf,i+10) - py1 +1
	if ( imgx < 1 )||( imgy < 1 ) : stt=-1 : return

	; 画像展開用の情報
	boff = lpeek(buf,i+16)+i ;bsize = lpeek(buf,i+20)
	aoff = lpeek(buf,i+12)+i ;asize = boff - aoff
	poff = lpeek(buf,i+24)+i ;psize = lpeek(buf,i+28)
	i+=32

	; BMP 画像を作成
	off = (1<<pbit)*3+26
	wid = (imgx*pbit+31)/32*4
	len = wid*imgy+off
	 sdim bmp, len
	wpoke bmp,  0, 0x4D42 : lpoke bmp,  2, len
	lpoke bmp, 10, off    : lpoke bmp, 14, 12
	wpoke bmp, 18, imgx   : wpoke bmp, 20, imgy
	wpoke bmp, 22, 1      : wpoke bmp, 24, pbit
	len = 26

	; パレット情報
	repeat pal
		poke bmp, len, peek(buf,i+2) : len++
		poke bmp, len, peek(buf,i  ) : len++
		poke bmp, len, peek(buf,i+1) : len++ : i+=3
	loop

	; ピクセル展開用の配列
	if postbl_chk == 0 {
	dim postbl,2,16 : postbl_chk=1
	postbl.0. 0 = 0,0 : postbl.0. 1 = 1,0 : postbl.0. 2 = 2,0 : postbl.0. 3 = 4,0
	postbl.0. 4 = 0,1 : postbl.0. 5 = 1,1 : postbl.0. 6 = 0,2 : postbl.0. 7 = 1,2
	postbl.0. 8 = 2,2 : postbl.0. 9 = 0,4 : postbl.0.10 = 1,4 : postbl.0.11 = 2,4
	postbl.0.12 = 0,8 : postbl.0.13 = 1,8 : postbl.0.14 = 2,8 : postbl.0.15 = 0,16
	}

	; ピクセル情報を展開
	mask=$80 : dim flag,imgx
	repeat imgy
		pf=0 : py = ( imgy-1-cnt )*wid + off

		repeat wid/2
			if cnt\2 == 0 {
				if ( peek(buf,aoff) & mask ) {
					flag.pf = flag.pf^peek(buf,boff) : boff++
				}
				mask=mask>>1 : if ( mask == 0 ) : mask=$80 : aoff++

				a = flag.pf/16
			} else {
				a = flag.pf\16 : pf++
			}

			; DecodePixGroup
			;---------- ---------- ----------
			if a > 0 {
				a = py + postbl.1.a*wid - postbl.0.a*2 : if a<off : a=off
				memcpy bmp, bmp, 2, py, a
			} else {
				wpoke bmp, py, ( peek(buf,poff) )|( peek(buf,poff+1)<<8 )
				poff+=2
			}
			;---------- ---------- ----------
			py += 2
		loop
	loop

	; BMPファイルとして読み込む
	memfile bmp : picload "MEM:a.bmp",p1
	stt=pbit
	return

;---------- ---------- ---------- ---------- ----------
#global


; サンプル
dialog "mag",16,"" : if stat!1 : end
sdim file,1024 : file=refstr

buffer 2 : mag_load file
	pbit = stat
	imgx = ginfo_winx
	imgy = ginfo_winy

gsel 0 : title ""+imgx+"x"+imgy+" "+pbit+"bit"
pos 0,0 : gcopy 2,0,0,imgx,imgy